【Access VBA】ログインフォームを使ったシステムの作り方

Option Compare Database

Function GetMD5Hash(strInput As String) As String
    Dim xmlObj As Object
    Dim byteData() As Byte
    Dim hashValue As String
    Dim i As Integer

    Set xmlObj = CreateObject("System.Security.Cryptography.MD5CryptoServiceProvider")
    byteData = StrConv(strInput, vbFromUnicode)
    
    Dim hash() As Byte
    hash = xmlObj.ComputeHash_2(byteData)

    For i = 0 To UBound(hash)
        hashValue = hashValue & LCase(Right("0" & Hex(hash(i)), 2))
    Next i

    GetMD5Hash = hashValue
End Function

Option Compare Database

Private Sub Form_Open(Cancel As Integer)
    DoCmd.ShowToolbar "Ribbon", acToolbarNo
    DoCmd.SelectObject acForm, "", True
    DoCmd.RunCommand acCmdWindowHide
End Sub

Private Sub tx社員コード_KeyPress(KeyAscii As Integer)
    '数字（0～9）とバックスペースのみ許可
    If Not (KeyAscii >= 48 And KeyAscii <= 57) And KeyAscii <> 8 Then
        KeyAscii = 0
    End If
End Sub

Private Sub cmdログイン_Click()
    Dim rs As DAO.Recordset
    Dim frm As Form
    
    If IsNull(Me.tx社員コード) = True Or IsNull(Me.txパスワード) = True Then
        MsgBox "社員コードまたはパスワードが入力されていません。", vbCritical
        Exit Sub
    End If
    
    Set rs = CurrentDb.OpenRecordset("SELECT * FROM M_社員マスタ WHERE 社員コード = '" & Me.tx社員コード & "' AND パスワード = '" & GetMD5Hash(Me.txパスワード.Value) & "'")
    
    If Not rs.EOF Then
        If rs!システム管理者 = True Then
            'ナビゲーションとリボンを表示
            DoCmd.ShowToolbar "Ribbon", acToolbarYes
            DoCmd.SelectObject acTable, , True
            
            DoCmd.OpenForm "F_メニュー_管理"
            Set frm = Forms("F_メニュー_管理")
        Else
            DoCmd.OpenForm "F_メニュー"
            Set frm = Forms("F_メニュー")
        End If
        
        frm.Controls("labelメッセージ").Caption = "お疲れさまです、" & rs!氏名 & " 様"

        DoCmd.Close acForm, "F_ログイン"
    Else
        MsgBox "社員コードまたはパスワードが間違っています。", vbExclamation
    End If
    
    rs.Close
    Set rs = Nothing
End Sub

Option Compare Database

Private Sub cmdログアウト_Click()
    DoCmd.OpenForm "F_ログイン"
    DoCmd.Close acForm, "F_メニュー"
End Sub

Option Compare Database

Private Sub cmdログアウト_Click()
    DoCmd.OpenForm "F_ログイン"
    DoCmd.Close acForm, "F_メニュー_管理"
End Sub

Private Sub cmd社員登録_Click()
    DoCmd.OpenForm "F_社員登録"
End Sub

Option Compare Database

Private Sub tx社員コード_KeyPress(KeyAscii As Integer)
    '数字（0～9）とバックスペースのみ許可
    If Not (KeyAscii >= 48 And KeyAscii <= 57) And KeyAscii <> 8 Then
        KeyAscii = 0
    End If
End Sub

Private Sub cmd登録_Click()
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim sql As String
    
    If IsNull(Me.tx氏名) = True Then
        MsgBox "氏名が入力されていません。", vbCritical
        Exit Sub
    End If
    
    If IsNull(Me.tx社員コード) = True Then
        MsgBox "社員コードが入力されていません。", vbCritical
        Exit Sub
    End If
    
    If IsNull(Me.txパスワード) = True Then
        MsgBox "パスワードが入力されていません。", vbCritical
        Exit Sub
    End If
    
    If Me.txパスワード <> Me.txパスワード確認用 Then
        MsgBox "パスワード(確認用)が入力されたパスワードと一致しません。"
        Exit Sub
    End If
    
    sql = "SELECT 社員コード FROM M_社員マスタ WHERE 社員コード = '" & Me.tx社員コード & "'"
    
    Set db = CurrentDb
    Set rs = db.OpenRecordset(sql, dbOpenSnapshot)
    If Not rs.EOF Then
        MsgBox "社員コード: " & Me.tx社員コード & "は既に登録されています。"
        Exit Sub
    End If
    
    Set rs = db.OpenRecordset("M_社員マスタ", dbOpenDynaset)
    
    rs.AddNew
    rs!社員コード = Me.tx社員コード.Value
    rs!氏名 = Me.tx氏名.Value
    rs!パスワード = GetMD5Hash(Me.txパスワード.Value)
    rs!システム管理者 = Me.checkシステム管理者
    
    rs.Update
    Set rs = Nothing
    Set db = Nothing
    
    Me.tx氏名 = Null
    Me.tx社員コード = Null
    Me.txパスワード = Null
    Me.txパスワード確認用 = Null
    Me.checkシステム管理者 = False
    
    MsgBox "社員が登録されました。", vbInformation
    
End Sub